Convert Currency in Number to Words (Indian Rupees) - MS Excel

By Karthikeyan , 17 May, 2014

Cheques, invoices, bills, receipts are needs to have the currency format both in Numerical and words. The below script can be used in Microsoft Excel / Word / Access or any VBA program supported applications to convert the currency in number format to words (English).

The below script adds 'and' joining word if it has paise (decimal part), otherwise if you want to have 'and' before 10s or 100s please check the following link for the version 2 of this script

Convert Currency in Number to Words (Indian Rupees) - Version 2


Function ConvertCurrencyToEnglish(ByVal MyNumber)
' Edited by Karthikeyan [email protected]
  Dim Temp
         Dim Rupees, Paise
         Dim DecimalPlace, Count
 
         ReDim Place(9) As String
         Place(2) = " Thousand "
         Place(3) = " lakh "
         Place(4) = " Crore "
 
 
         ' Convert MyNumber to a string, trimming extra spaces.
         MyNumber = Trim(Str(MyNumber))
 
         ' Find decimal place.
         DecimalPlace = InStr(MyNumber, ".")
 
         ' If we find decimal place...
         If DecimalPlace > 0 Then
            ' Convert Paise
            Temp = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)
            ' Hi! Note the above line Mid function it gives right portion
            ' after the decimal point
            'if only . and no numbers such as 789. accures, mid returns nothing
            ' to avoid error we added 00
            ' Left function gives only left portion of the string with specified places here 2
 
 
            Paise = ConvertTens(Temp)
 
 
            ' Strip off paise from remainder to convert.
            MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
         End If
 
         Count = 1
        If MyNumber <> "" Then
 
            ' Convert last 3 digits of MyNumber to Indian Rupees.
            Temp = ConvertHundreds(Right(MyNumber, 3))
 
            If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
 
            If Len(MyNumber) > 3 Then
               ' Remove last 3 converted digits from MyNumber.
               MyNumber = Left(MyNumber, Len(MyNumber) - 3)
            Else
               MyNumber = ""
            End If
 
        End If
 
            ' convert last two digits to of mynumber
            Count = 2
 
            Do While MyNumber <> ""
            Temp = ConvertTens(Right("0" & MyNumber, 2))
 
            If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
            If Len(MyNumber) > 2 Then
               ' Remove last 2 converted digits from MyNumber.
               MyNumber = Left(MyNumber, Len(MyNumber) - 2)
 
            Else
               MyNumber = ""
            End If
            Count = Count + 1
 
            Loop
 
 
 
 
         ' Clean up rupees.
         Select Case Rupees
            Case ""
               Rupees = ""
            Case "One"
               Rupees = "Rupee One"
            Case Else
               Rupees = "Rupees " & Rupees
         End Select
 
         ' Clean up paise.
         Select Case Paise
            Case ""
               Paise = ""
            Case "One"
               Paise = "One Paise"
            Case Else
               Paise = Paise & " Paise"
         End Select
         
         If Rupees = "" Then
         ConvertCurrencyToEnglish = Paise & " Only"
         ElseIf Paise = "" Then
         ConvertCurrencyToEnglish = Rupees & " Only"
         Else
         ConvertCurrencyToEnglish = Rupees & " and " & Paise & " Only"
         End If
         
End Function
 
 
Private Function ConvertDigit(ByVal MyDigit)
        Select Case Val(MyDigit)
            Case 1: ConvertDigit = "One"
            Case 2: ConvertDigit = "Two"
            Case 3: ConvertDigit = "Three"
            Case 4: ConvertDigit = "Four"
            Case 5: ConvertDigit = "Five"
            Case 6: ConvertDigit = "Six"
            Case 7: ConvertDigit = "Seven"
            Case 8: ConvertDigit = "Eight"
            Case 9: ConvertDigit = "Nine"
            Case Else: ConvertDigit = ""
         End Select
 
End Function
 
Private Function ConvertHundreds(ByVal MyNumber)
    Dim Result As String
 
         ' Exit if there is nothing to convert.
         If Val(MyNumber) = 0 Then Exit Function
 
         ' Append leading zeros to number.
         MyNumber = Right("000" & MyNumber, 3)
 
         ' Do we have a hundreds place digit to convert?
         If Left(MyNumber, 1) <> "0" Then
            Result = ConvertDigit(Left(MyNumber, 1)) & " Hundred "
         End If
 
         ' Do we have a tens place digit to convert?
         If Mid(MyNumber, 2, 1) <> "0" Then
            Result = Result & ConvertTens(Mid(MyNumber, 2))
         Else
            ' If not, then convert the ones place digit.
            Result = Result & ConvertDigit(Mid(MyNumber, 3))
         End If
 
         ConvertHundreds = Trim(Result)
End Function
 
 
Private Function ConvertTens(ByVal MyTens)
          Dim Result As String
 
         ' Is value between 10 and 19?
         If Val(Left(MyTens, 1)) = 1 Then
            Select Case Val(MyTens)
               Case 10: Result = "Ten"
               Case 11: Result = "Eleven"
               Case 12: Result = "Twelve"
               Case 13: Result = "Thirteen"
               Case 14: Result = "Fourteen"
               Case 15: Result = "Fifteen"
               Case 16: Result = "Sixteen"
               Case 17: Result = "Seventeen"
               Case 18: Result = "Eighteen"
               Case 19: Result = "Nineteen"
               Case Else
            End Select
         Else
            ' .. otherwise it's between 20 and 99.
            Select Case Val(Left(MyTens, 1))
               Case 2: Result = "Twenty "
               Case 3: Result = "Thirty "
               Case 4: Result = "Forty "
               Case 5: Result = "Fifty "
               Case 6: Result = "Sixty "
               Case 7: Result = "Seventy "
               Case 8: Result = "Eighty "
               Case 9: Result = "Ninety "
               Case Else
            End Select
 
            ' Convert ones place digit.
            Result = Result & ConvertDigit(Right(MyTens, 1))
         End If
 
         ConvertTens = Result
End Function

Download this

How to use this code?

Click on Developer Tab in MS office (Word / Excel / Access). If Developer Tab not appears, click here to know the way to enable this.
Click Visual Basic, then VBA application development window will open
Now right click in Project pane, insert -> Module

Inserting VBA module in MS Office

Now paste the above code and save it as Macro Enabled document. (For excel save with extension .xlsm)
Now you can use the formula '=ConvertCurrencyToEnglish()'

Currency in Number to Worlds - Excel

MS Access & MS Word Implementations

Online converter

Update 02-03-2017 : Code updated to show 'Rupee/Rupees' as prefix and 'Only' as suffix.

How to use video :

Comments31

Same way just suffix "only" word in formula.
e.g. = "Total " & ConvertCurrencyToEnglish(A1) &" only"

thnx dear some more hlp how to add word only in the last like (Total One lac Twenty Two Thousand One Hundred Fifty Four Rupees only

Just add the "Total " prefix in formula.
e.g. = "Total " & ConvertCurrencyToEnglish(A1)

how to add word Total in start like ( TOTAL FORTY FIVE THOUSAND SIX HUNDRED AND FIFTY NINE ONLY)

Just change the line 82 as follows
Rupees = "Rupees " & Rupees

Great job!

Thank you would be a mere thing to say.

But as I could not do anything apart from saying “Big Thank You”

dear admin, please help me for using those code. im new in access. im complete it in my database. please let me know how to use it in my access report. im waiting for ur earlier replay.

now you can convert any number into word using "Desi Tools" App, it also works on mobile

https://www.microsoft.com/s...

Need windows 8.1 or higher on pc or phone.

Now you can convert any number to word in indian style with "Desi Tool" App

https://www.microsoft.com/s...

It work on PC and Phone both

Need window 8 or higher..

Enjoy its free!!!

Save the excel sheet macro enabled format. i.e.xlsm

dear sir,

whenever i open the sheet i have insert again the same formula.

what is solution to solver at once.

it worked in excel

Not just the code, you have to use the code in Excel and save the excel file in xlsm format.

i have save above code in .xlam format but does not work.

what if i want the "rupees" or "paise" first?

how do i append " only" at the end & "Rupees" at start

big thank you

Dear May i have one format excel file for this? any file in which u have applied this code..

thanks

This script works perfectly in MS Access too. If the value is 0 no message will be printed.

Then, the output is entirely based on your preference, when you trigger the function either in form load or after updating the source field. For example : =ConvertCurrencyToEnglish([Amount]) can be use in a field which refers source field [Amount] and converts the number to words.

Does this convert "0" into "Zero" on formload when entire form has blank data in access 2007?If yes/No please let me know how?

Check this post

https://www.livetolearn.in/...

how does it work in Ms word

Thank you it is working in my Excel-2007

If there is no paise or decimals in input number, then it will not be displayed.

what if i don't want the "paise" or decimals to display?

nice.

You can convert the above code to Java very easy.

Big Thanks. Saved a lot of typing time for me..

can i get a similar one written in java..

how does it work in Ms word

Add new comment